microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

52ae76d3df86bce15f0bd7ee03bbd499cfaf35e2

Find a branch or tag

Branches

52ae76d3df86bce15f0bd7ee03bbd499cfaf35e2

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

203lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT CMAKE_SYSTEM_NAME STREQUAL "Android")`
5	`find_package(JNI REQUIRED)`
6	`endif()`
7
8	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
9	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
10	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
11
12	`# use the gradle wrapper if it exists`
13	`if(EXISTS "${JAVA_ROOT}/gradlew")`
14	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
15	`else()`
16	`# fall back to gradle on our PATH`
17	`find_program(GRADLE_EXECUTABLE gradle)`
18	`if(NOT GRADLE_EXECUTABLE)`
19	`message(SEND_ERROR "Gradle installation not found")`
20	`endif()`
21	`endif()`
22	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
23
24	`# Specify the Java source files`
25	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
26	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
27	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
28	`# this jar is solely used to signaling mechanism for dependency management in CMake`
29	`# if any of the Java sources change, the jar (and generated headers) will be regenerated and the onnxruntime_extensions4j_jni target will be rebuilt`
30	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
31	`if(WIN32)`
32	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
33	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
34	`# For Android build, we may run gradle multiple times in same build,`
35	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
36	`# it is better to not keep a daemon running`
37	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
38	`endif()`
39
40	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
41	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
42	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP} DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src})`
43	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
44	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
45	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
46
47	`# Specify the native sources`
48	`file(GLOB onnxruntime_extensions4j_native_src`
49	`"${JAVA_ROOT}/src/main/native/*.c"`
50	`"${JAVA_ROOT}/src/main/native/*.h"`
51	`"${PROJECT_SOURCE_DIR}/include/*.h"`
52	`)`
53	`# Build the JNI library`
54	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
55
56	`# depend on java sources. if they change, the JNI should recompile`
57	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
58	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
59	`# the JNI headers are generated in the onnxruntime_extensions4j target`
60	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
61	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
62	`standardize_output_folder(onnxruntime_extensions4j_jni)`
63
64	`set(JAVA_PACKAGE_OUTPUT_DIR ${JAVA_OUTPUT_DIR}/build)`
65	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_OUTPUT_DIR})`
66	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
67	`set(ANDROID_PACKAGE_OUTPUT_DIR ${JAVA_PACKAGE_OUTPUT_DIR}/android)`
68	`file(MAKE_DIRECTORY ${ANDROID_PACKAGE_OUTPUT_DIR})`
69	`endif()`
70
71	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
72	`if (OCOS_ENABLE_SPM_TOKENIZER)`
73	`target_link_libraries(onnxruntime_extensions4j_jni PUBLIC log)`
74	`endif()`
75	`endif()`
76	`# Set platform and arch for packaging`
77	`# Checks the names set by MLAS on non-Windows platforms first`
78	`if(APPLE)`
79	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
80	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
81	`if(ONNXRUNTIME4J_OSX_ARCH)`
82	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
83	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
84	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
85	`else()`
86	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
87	`endif()`
88	`else()`
89	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
90	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
91	`endif()`
92	`if(JNI_ARCH STREQUAL "x86_64")`
93	`set(JNI_ARCH x64)`
94	`elseif(JNI_ARCH STREQUAL "arm64")`
95	`set(JNI_ARCH aarch64)`
96	`endif()`
97	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
98	`set(JNI_ARCH ${ANDROID_ABI})`
99	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
100	`set(JNI_ARCH x64)`
101	`else()`
102	`# Now mirror the checks used with MSVC`
103	`if(MSVC)`
104	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
105	`set(JNI_ARCH aarch64)`
106	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
107	`set(JNI_ARCH x64)`
108	`else()`
109	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
110	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
111	`endif()`
112	`else()`
113	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
114	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
115	`endif()`
116	`endif()`
117
118	`if (WIN32)`
119	`set(JAVA_PLAT "win")`
120	`elseif (APPLE)`
121	`set(JAVA_PLAT "osx")`
122	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
123	`set(JAVA_PLAT "linux")`
124	`else()`
125	`# We don't do distribution for Android`
126	`# Set for completeness`
127	`set(JAVA_PLAT "android")`
128	`endif()`
129
130	`# Similar to Nuget schema`
131	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
132
133	`# expose native libraries to the gradle build process`
134	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
135	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
136	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
137	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
138	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
139	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
140	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
141
142	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
143	`if (WIN32)`
144	`#Our static analysis plugin set /p:LinkCompiled=false`
145	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
146	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
147	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
148	`endif()`
149	`else()`
150	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
151	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
152	`endif()`
153
154	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
155	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
156	`if(WIN32)`
157	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
158	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
159	`# For Android build, we may run gradle multiple times in same build,`
160	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
161	`# it is better to not keep a daemon running`
162	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
163	`endif()`
164
165	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
166	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
167
168	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
169	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
170	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
171	`file(MAKE_DIRECTORY ${ANDROID_PACKAGE_JNILIBS_DIR})`
172	`file(MAKE_DIRECTORY ${ANDROID_PACKAGE_ABI_DIR})`
173
174	`# Copy onnxruntime_extensions4j_jni.so for building Android AAR package`
175	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
176	`POST_BUILD COMMAND ${CMAKE_COMMAND}`
177	`-E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
178	`# Generate the Android AAR package`
179	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
180	`POST_BUILD COMMAND ${GRADLE_EXECUTABLE}`
181	`-b build-android.gradle -c settings-android.gradle build`
182	`-DjniLibsDir=${ANDROID_PACKAGE_JNILIBS_DIR} -DbuildDir=${ANDROID_PACKAGE_OUTPUT_DIR} -DminSdkVer=${ANDROID_MIN_SDK} -DndkVer=${ANDROID_NDK_VERSION}`
183	`WORKING_DIRECTORY ${JAVA_ROOT})`
184
185	`set(ANDROID_TEST_PACKAGE_ROOT ${JAVA_ROOT}/src/test/android)`
186	`set(ANDROID_TEST_PACKAGE_DIR ${JAVA_OUTPUT_DIR}/androidtest/android)`
187	`#copy the androidtest project into cmake binary directory`
188	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_DIR}/androidtest)`
189	`file(COPY ${ANDROID_TEST_PACKAGE_ROOT} DESTINATION ${JAVA_OUTPUT_DIR}/androidtest)`
190	`set(ANDROID_TEST_PACKAGE_LIB_DIR ${ANDROID_TEST_PACKAGE_DIR}/app/libs)`
191	`file(MAKE_DIRECTORY ${ANDROID_TEST_PACKAGE_LIB_DIR})`
192	`# Copy the built Android AAR package to libs folder of our test app`
193	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
194	`POST_BUILD COMMAND ${CMAKE_COMMAND}`
195	`-E copy_if_different ${ANDROID_PACKAGE_OUTPUT_DIR}/outputs/aar/onnxruntime-extensions-debug.aar ${ANDROID_TEST_PACKAGE_LIB_DIR})`
196	`# Build Android test apk for java package`
197	`file(TO_NATIVE_PATH ./gradlew GRADLEW)`
198	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
199	`POST_BUILD COMMAND ${GRADLEW} clean WORKING_DIRECTORY ${ANDROID_TEST_PACKAGE_DIR})`
200	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
201	`POST_BUILD COMMAND ${GRADLEW} assembleDebug assembleDebugAndroidTest`
202	`WORKING_DIRECTORY ${ANDROID_TEST_PACKAGE_DIR})`
203	`endif()`
204

microsoft/onnxruntime-extensions

Branches

Tags

Clone