microsoft/onnxruntime-extensions
Publicmirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable
cmake/ext_ortlib.cmake
41lines · modecode
| 1 | if(_ONNXRUNTIME_EMBEDDED) |
| 2 | set(ONNXRUNTIME_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/../include/onnxruntime/core/session) |
| 3 | set(ONNXRUNTIME_LIB_DIR "") |
| 4 | else() |
| 5 | set(ONNXRUNTIME_VER "1.10.0" CACHE STRING "ONNX Runtime version") |
| 6 | |
| 7 | if(CMAKE_HOST_APPLE) |
| 8 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-osx-universal2-${ONNXRUNTIME_VER}.tgz") |
| 9 | elseif(CMAKE_HOST_WIN32) |
| 10 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-win-x64-${ONNXRUNTIME_VER}.zip") |
| 11 | |
| 12 | if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm64") |
| 13 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-win-arm64-${ONNXRUNTIME_VER}.zip") |
| 14 | endif() |
| 15 | else() |
| 16 | # Linux or other, using Linux package to retrieve the headers |
| 17 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-linux-x64-${ONNXRUNTIME_VER}.tgz") |
| 18 | |
| 19 | if(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64") |
| 20 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-linux-aarch64-${ONNXRUNTIME_VER}.tgz") |
| 21 | endif() |
| 22 | endif() |
| 23 | |
| 24 | # Avoid warning about DOWNLOAD_EXTRACT_TIMESTAMP in CMake 3.24: |
| 25 | if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.24.0") |
| 26 | cmake_policy(SET CMP0135 NEW) |
| 27 | endif() |
| 28 | |
| 29 | message(STATUS "ONNX Runtime URL suffix: ${ONNXRUNTIME_URL}") |
| 30 | FetchContent_Declare( |
| 31 | onnxruntime |
| 32 | URL https://github.com/microsoft/onnxruntime/releases/download/${ONNXRUNTIME_URL} |
| 33 | ) |
| 34 | FetchContent_makeAvailable(onnxruntime) |
| 35 | set(ONNXRUNTIME_INCLUDE_DIR ${onnxruntime_SOURCE_DIR}/include) |
| 36 | set(ONNXRUNTIME_LIB_DIR ${onnxruntime_SOURCE_DIR}/lib) |
| 37 | endif() |
| 38 | |
| 39 | if(NOT EXISTS ${ONNXRUNTIME_INCLUDE_DIR}) |
| 40 | message(FATAL_ERROR "ONNX Runtime headers not found at ${ONNXRUNTIME_INCLUDE_DIR}") |
| 41 | endif() |
| 42 | |