microsoft/TypeAgent
Publicmirrored from https://github.com/microsoft/TypeAgentAvailable
ts/tools/scripts/install-shell.cmd
128lines · modecode
| 1 | :: Copyright (c) Microsoft Corporation. |
| 2 | :: Licensed under the MIT License. |
| 3 | |
| 4 | @echo off |
| 5 | setlocal |
| 6 | |
| 7 | IF "%1" == "" ( |
| 8 | call :Error No storage account specified. |
| 9 | exit /B 1 |
| 10 | ) |
| 11 | |
| 12 | set STORAGE=%1 |
| 13 | IF "%2" == "" ( |
| 14 | set CONTAINER=%1 |
| 15 | ) ELSE ( |
| 16 | set CONTAINER=%2 |
| 17 | ) |
| 18 | |
| 19 | IF "%3" == "" ( |
| 20 | set CHANNEL=lkg |
| 21 | ) ELSE ( |
| 22 | set CHANNEL=%3 |
| 23 | ) |
| 24 | |
| 25 | set DEST=%TEMP%\install-shell |
| 26 | mkdir %DEST% > nul 2>&1 |
| 27 | IF ERRORLEVEL 1 ( |
| 28 | call :Error Failed to create %DEST% directory. |
| 29 | exit /B 1 |
| 30 | ) |
| 31 | del /Q /S %DEST%\* > nul 2>&1 |
| 32 | IF ERRORLEVEL 1 ( |
| 33 | call :Error Failed to delete files in %DEST% directory. |
| 34 | exit /B 1 |
| 35 | ) |
| 36 | |
| 37 | call :Info Getting TypeAgent Shell from [30m[96m%CHANNEL%[0m channel in [30m[93m%STORAGE%/%CONTAINER%[0m. |
| 38 | call :DownloadYml %PACKAGE% |
| 39 | IF ERRORLEVEL 1 ( |
| 40 | call :Cleanup |
| 41 | exit /B 1 |
| 42 | ) |
| 43 | |
| 44 | FOR /F "tokens=1-2 delims=:" %%i IN (%DEST%\%CHANNEL%.yml) DO ( |
| 45 | IF "%%i" == "path" ( |
| 46 | set PACKAGE=%%j |
| 47 | ) |
| 48 | ) |
| 49 | |
| 50 | IF "%PACKAGE%" == "" ( |
| 51 | call :Error Failed to find path in %CHANNEL%.yml. Ensure that the file is valid. |
| 52 | call :Cleanup |
| 53 | exit /B 1 |
| 54 | ) |
| 55 | |
| 56 | call :DownloadPackage %PACKAGE% |
| 57 | IF ERRORLEVEL 1 ( |
| 58 | call :Cleanup |
| 59 | exit /B 1 |
| 60 | ) |
| 61 | |
| 62 | |
| 63 | call :ExecutePackage %PACKAGE% |
| 64 | IF ERRORLEVEL 1 ( |
| 65 | call :Cleanup |
| 66 | exit /B 1 |
| 67 | ) |
| 68 | |
| 69 | call :Cleanup |
| 70 | exit /B 0 |
| 71 | |
| 72 | :DownloadYml |
| 73 | call :Info Downloading %CHANNEL%.yml |
| 74 | call az storage blob download --account-name %STORAGE% --container-name %CONTAINER% --name %CHANNEL%.yml --file %DEST%\%CHANNEL%.yml --overwrite --auth-mode login > %DEST%\install-shell.log 2>&1 |
| 75 | IF ERRORLEVEL 1 ( |
| 76 | call :Error Failed to download %CHANNEL%.yml from %STORAGE%/%CONTAINER%. |
| 77 | call :Error Ensure you that you are logged into azure cli with 'az login' and have access to the storage account. |
| 78 | type %DEST%\install-shell.log |
| 79 | exit /B 1 |
| 80 | ) |
| 81 | exit /B 0 |
| 82 | |
| 83 | :DownloadPackage |
| 84 | call :Info Downloading %1 |
| 85 | call az storage blob download --account-name %STORAGE% --container-name %CONTAINER% --name %1 --file %DEST%\%1 --overwrite --auth-mode login > %DEST%\install-shell.log 2>&1 |
| 86 | IF ERRORLEVEL 1 ( |
| 87 | call :Error Failed to download %1 from %STORAGE%/%CONTAINER%. |
| 88 | type %DEST%\install-shell.log |
| 89 | exit /B 1 |
| 90 | ) |
| 91 | exit /B 0 |
| 92 | |
| 93 | :ExecutePackage |
| 94 | call :Info Running %1 |
| 95 | %DEST%\%1 > %DEST%\install-shell.log 2>&1 |
| 96 | IF ERRORLEVEL 1 ( |
| 97 | call :Error Failed to install %1 |
| 98 | type %DEST%\install-shell.log |
| 99 | exit /B 1 |
| 100 | ) |
| 101 | |
| 102 | call :Success %1 installed successfully. |
| 103 | call :Success TypeAgent Shell will start automatically. |
| 104 | exit /B 0 |
| 105 | |
| 106 | :Usage |
| 107 | echo Usage: %0 ^<storage^> [^<container^>] [^<channel^>] |
| 108 | echo ^<storage^> - The name of the storage account to use. |
| 109 | echo ^<container^> - The name of the container to use. ^<storage^> will be used if not specified. |
| 110 | echo ^<channel^> - The channel to use. Default to 'lkg' if not specified. |
| 111 | exit /B 0 |
| 112 | |
| 113 | :Info |
| 114 | echo [30m[90mINFO: %*[0m |
| 115 | exit /B 0 |
| 116 | |
| 117 | :Success |
| 118 | echo [30m[92mSUCCESS: %*[0m |
| 119 | exit /B 0 |
| 120 | |
| 121 | :Error |
| 122 | echo [30m[91mERROR: %*[0m |
| 123 | exit /B 0 |
| 124 | |
| 125 | :Cleanup |
| 126 | del /Q /S %DEST%\* > nul 2>&1 |
| 127 | rmdir /S /Q %DEST% > nul 2>&1 |
| 128 | exit /B 0 |