microsoft/onnxruntime-extensions

Public

mirrored from https://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

08659eae90f5df5cce12d5e02e6c97a0474d30ce

Find a branch or tag

Branches

08659eae90f5df5cce12d5e02e6c97a0474d30ce

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

193lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT CMAKE_SYSTEM_NAME STREQUAL "Android")`
5	`find_package(JNI REQUIRED)`
6	`endif()`
7
8	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
9	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
10	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
11
12	`# use the gradle wrapper if it exists`
13	`if(EXISTS "${JAVA_ROOT}/gradlew")`
14	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
15	`else()`
16	`# fall back to gradle on our PATH`
17	`find_program(GRADLE_EXECUTABLE gradle)`
18	`if(NOT GRADLE_EXECUTABLE)`
19	`message(SEND_ERROR "Gradle installation not found")`
20	`endif()`
21	`endif()`
22	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
23
24	`# Specify the Java source files`
25	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
26	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
27	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
28	`# this jar is solely used to signaling mechanism for dependency management in CMake`
29	`# if any of the Java sources change, the jar (and generated headers) will be regenerated and the onnxruntime_extensions4j_jni target will be rebuilt`
30	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
31	`if(WIN32)`
32	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
33	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
34	`# For Android build, we may run gradle multiple times in same build,`
35	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
36	`# it is better to not keep a daemon running`
37	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
38	`endif()`
39
40	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
41	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR} COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP} DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src})`
42	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
43	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
44	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
45
46	`# Specify the native sources`
47	`file(GLOB onnxruntime_extensions4j_native_src`
48	`"${JAVA_ROOT}/src/main/native/*.c"`
49	`"${JAVA_ROOT}/src/main/native/*.h"`
50	`"${PROJECT_SOURCE_DIR}/include/*.h"`
51	`)`
52	`# Build the JNI library`
53	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
54
55	`# depend on java sources. if they change, the JNI should recompile`
56	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
57	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
58	`# the JNI headers are generated in the onnxruntime_extensions4j target`
59	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
60	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
61	`standardize_output_folder(onnxruntime_extensions4j_jni)`
62
63	`set(JAVA_PACKAGE_OUTPUT_DIR ${JAVA_OUTPUT_DIR}/build)`
64	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_OUTPUT_DIR})`
65	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
66	`set(ANDROID_PACKAGE_OUTPUT_DIR ${JAVA_PACKAGE_OUTPUT_DIR}/android)`
67	`file(MAKE_DIRECTORY ${ANDROID_PACKAGE_OUTPUT_DIR})`
68	`endif()`
69
70	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
71	`if (OCOS_ENABLE_SPM_TOKENIZER)`
72	`target_link_libraries(onnxruntime_extensions4j_jni PUBLIC log)`
73	`endif()`
74	`endif()`
75	`# Set platform and arch for packaging`
76	`# Checks the names set by MLAS on non-Windows platforms first`
77	`if(APPLE)`
78	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
79	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
80	`if(ONNXRUNTIME4J_OSX_ARCH)`
81	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
82	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
83	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
84	`else()`
85	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
86	`endif()`
87	`else()`
88	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
89	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
90	`endif()`
91	`if(JNI_ARCH STREQUAL "x86_64")`
92	`set(JNI_ARCH x64)`
93	`elseif(JNI_ARCH STREQUAL "arm64")`
94	`set(JNI_ARCH aarch64)`
95	`endif()`
96	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
97	`set(JNI_ARCH ${ANDROID_ABI})`
98	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
99	`set(JNI_ARCH x64)`
100	`else()`
101	`# Now mirror the checks used with MSVC`
102	`if(MSVC)`
103	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
104	`set(JNI_ARCH aarch64)`
105	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
106	`set(JNI_ARCH x64)`
107	`else()`
108	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
109	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
110	`endif()`
111	`else()`
112	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
113	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
114	`endif()`
115	`endif()`
116
117	`if (WIN32)`
118	`set(JAVA_PLAT "win")`
119	`elseif (APPLE)`
120	`set(JAVA_PLAT "osx")`
121	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
122	`set(JAVA_PLAT "linux")`
123	`else()`
124	`# We don't do distribution for Android`
125	`# Set for completeness`
126	`set(JAVA_PLAT "android")`
127	`endif()`
128
129	`# Similar to Nuget schema`
130	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
131
132	`# expose native libraries to the gradle build process`
133	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
134	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
135	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
136	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
137	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
138	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
139	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
140
141	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
142	`if (WIN32)`
143	`#Our static analysis plugin set /p:LinkCompiled=false`
144	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
145	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions> ${JAVA_PACKAGE_LIB_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions>)`
146	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
147	`endif()`
148	`else()`
149	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions> ${JAVA_PACKAGE_LIB_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions>)`
150	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
151	`endif()`
152
153	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
154	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
155	`if(WIN32)`
156	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
157	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
158	`# For Android build, we may run gradle multiple times in same build,`
159	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
160	`# it is better to not keep a daemon running`
161	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
162	`endif()`
163
164	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
165	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
166
167	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
168	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
169	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
170	`file(MAKE_DIRECTORY ${ANDROID_PACKAGE_JNILIBS_DIR})`
171	`file(MAKE_DIRECTORY ${ANDROID_PACKAGE_ABI_DIR})`
172
173	`# Copy onnxruntime_extensions.so and onnxruntime_extensions4j_jni.so for building Android AAR package`
174	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions> ${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions>)`
175	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
176	`# Generate the Android AAR package`
177	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} -b build-android.gradle -c settings-android.gradle build -DjniLibsDir=${ANDROID_PACKAGE_JNILIBS_DIR} -DbuildDir=${ANDROID_PACKAGE_OUTPUT_DIR} -DminSdkVer=${ANDROID_MIN_SDK} -DheadersDir=${ANDROID_HEADERS_DIR} WORKING_DIRECTORY ${JAVA_ROOT})`
178
179	`if (onnxruntime_extensions_BUILD_UNIT_TESTS)`
180	`set(ANDROID_TEST_PACKAGE_ROOT ${JAVA_ROOT}/src/test/android)`
181	`set(ANDROID_TEST_PACKAGE_DIR ${JAVA_OUTPUT_DIR}/androidtest/android)`
182	`#copy the androidtest project into cmake binary directory`
183	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_DIR}/androidtest)`
184	`file(COPY ${ANDROID_TEST_PACKAGE_ROOT} DESTINATION ${JAVA_OUTPUT_DIR}/androidtest)`
185	`set(ANDROID_TEST_PACKAGE_LIB_DIR ${ANDROID_TEST_PACKAGE_DIR}/app/libs)`
186	`file(MAKE_DIRECTORY ${ANDROID_TEST_PACKAGE_LIB_DIR})`
187	`# Copy the built Android AAR package to libs folder of our test app`
188	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${ANDROID_PACKAGE_OUTPUT_DIR}/outputs/aar/onnxruntime_extensions-debug.aar ${ANDROID_TEST_PACKAGE_LIB_DIR}/onnxruntime_extensions-mobile.aar)`
189	`# Build Android test apk for java package`
190	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} clean WORKING_DIRECTORY ${ANDROID_TEST_PACKAGE_DIR})`
191	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} assembleDebug assembleDebugAndroidTest -DminSdkVer=${ANDROID_MIN_SDK} WORKING_DIRECTORY ${ANDROID_TEST_PACKAGE_DIR})`
192	`endif()`
193	`endif()`
194

microsoft/onnxruntime-extensions

Branches

Tags

Clone