microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

176c1d013864044bcc0747b908bdd32048669401

Find a branch or tag

Branches

176c1d013864044bcc0747b908bdd32048669401

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

225lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT ANDROID)`
5	`set(JAVA_AWT_LIBRARY NotNeeded)`
6	`set(JAVA_AWT_INCLUDE_PATH NotNeeded)`
7	`find_package(JNI REQUIRED)`
8	`endif()`
9
10	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
11	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
12	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
13
14	`# use the gradle wrapper if it exists`
15	`if(EXISTS "${JAVA_ROOT}/gradlew")`
16	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
17	`else()`
18	`# fall back to gradle on our PATH`
19	`find_program(GRADLE_EXECUTABLE gradle)`
20	`if(NOT GRADLE_EXECUTABLE)`
21	`message(SEND_ERROR "Gradle installation not found")`
22	`endif()`
23	`endif()`
24	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
25
26	`# Specify the Java source files`
27	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
28	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
29	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
30	`# this jar is solely used to signaling mechanism for dependency management in CMake`
31	`# if any of the Java sources change, the jar (and generated headers) will be regenerated`
32	`# and the onnxruntime_extensions4j_jni target will be rebuilt`
33	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
34	`if(WIN32)`
35	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
36	`elseif (ANDROID)`
37	`# For Android build, we may run gradle multiple times in same build,`
38	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
39	`# it is better to not keep a daemon running`
40	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
41	`endif()`
42
43	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
44	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
45	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP}`
46	`DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src} ortcustomops)`
47	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
48	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
49	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
50
51	`# Specify the native sources`
52	`file(GLOB onnxruntime_extensions4j_native_src`
53	`"${JAVA_ROOT}/src/main/native/*.c"`
54	`"${JAVA_ROOT}/src/main/native/*.h"`
55	`"${PROJECT_SOURCE_DIR}/include/*.h"`
56	`)`
57	`if(WIN32)`
58	`list(APPEND onnxruntime_extensions4j_native_src "${JAVA_ROOT}/ortx_jni.def")`
59	`endif()`
60	`# Build the JNI library`
61	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
62
63	`# depend on java sources. if they change, the JNI should recompile`
64	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
65	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
66	`# the JNI headers are generated in the onnxruntime_extensions4j target`
67	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
68
69	`# use shared lib for extensions on Android as NuGet requires the extensions .so`
70	`if (ANDROID AND _BUILD_SHARED_LIBRARY)`
71	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE extensions_shared)`
72	`else()`
73	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
74	`endif()`
75
76	`if(LINUX)`
77	`set_property(TARGET onnxruntime_extensions4j_jni APPEND_STRING PROPERTY LINK_FLAGS`
78	`" -Wl,--version-script -Wl,${JAVA_ROOT}/ortx_jni.ver")`
79	`# strip if not a debug build`
80	`if(NOT CMAKE_BUILD_TYPE STREQUAL "Debug")`
81	`set_property(TARGET onnxruntime_extensions4j_jni APPEND_STRING PROPERTY LINK_FLAGS " -Wl,-s")`
82	`endif()`
83	`endif()`
84
85	`standardize_output_folder(onnxruntime_extensions4j_jni)`
86
87	`# Set platform and arch for packaging`
88	`# Checks the names set by MLAS on non-Windows platforms first`
89	`if(APPLE)`
90	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
91	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
92	`if(ONNXRUNTIME4J_OSX_ARCH)`
93	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
94	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
95	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
96	`else()`
97	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
98	`endif()`
99	`else()`
100	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
101	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
102	`endif()`
103	`if(JNI_ARCH STREQUAL "x86_64")`
104	`set(JNI_ARCH x64)`
105	`elseif(JNI_ARCH STREQUAL "arm64")`
106	`set(JNI_ARCH aarch64)`
107	`endif()`
108	`elseif (ANDROID)`
109	`set(JNI_ARCH ${ANDROID_ABI})`
110	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
111	`set(JNI_ARCH x64)`
112	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "aarch64")`
113	`set(JNI_ARCH aarch64)`
114	`else()`
115	`# Now mirror the checks used with MSVC`
116	`if(MSVC)`
117	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
118	`set(JNI_ARCH aarch64)`
119	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
120	`set(JNI_ARCH x64)`
121	`else()`
122	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
123	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
124	`endif()`
125	`else()`
126	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
127	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
128	`endif()`
129	`endif()`
130
131	`if (WIN32)`
132	`set(JAVA_PLAT "win")`
133	`elseif (APPLE)`
134	`set(JAVA_PLAT "osx")`
135	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
136	`set(JAVA_PLAT "linux")`
137	`else()`
138	`# We don't do distribution for Android`
139	`# Set for completeness`
140	`set(JAVA_PLAT "android")`
141	`endif()`
142
143	`# Similar to Nuget schema`
144	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
145
146	`# expose native libraries to the gradle build process`
147	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
148	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
149	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
150	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
151	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
152	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
153	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
154
155	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
156	`if (WIN32)`
157	`#Our static analysis plugin set /p:LinkCompiled=false`
158	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
159	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
160	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
161	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
162	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
163	`endif()`
164	`else()`
165	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
166	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
167	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
168	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
169	`endif()`
170
171	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
172	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
173	`if(WIN32)`
174	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
175	`elseif (ANDROID)`
176	`# For Android build, we may run gradle multiple times in same build,`
177	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
178	`# it is better to not keep a daemon running`
179	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
180	`endif()`
181
182	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
183	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
184	`POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
185
186	`if (ANDROID)`
187	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
188	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
189
190	`# Copy onnxruntime_extensions4j_jni.so and ortextensions.so for building Android AAR package and use in NuGet`
191	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
192	`POST_BUILD`
193	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
194	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
195	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
196	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
197
198	`if (_BUILD_SHARED_LIBRARY)`
199	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
200	`POST_BUILD`
201	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
202	`$<TARGET_FILE:extensions_shared>`
203	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:extensions_shared>)`
204	`endif()`
205
206	`if (OCOS_ENABLE_AZURE)`
207	`# if we do a shared build of curl/openssl libcurl.so will exist, and we need to copy these files`
208	`# for inclusion in the AAR`
209	`if(EXISTS "${CURL_ROOT_DIR}/lib/libcurl.so")`
210	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
211	`POST_BUILD`
212	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
213	`$<TARGET_FILE:OpenSSL::Crypto>`
214	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::Crypto>`
215	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
216	`$<TARGET_FILE:OpenSSL::SSL>`
217	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::SSL>`
218	`# not sure why but we need to use the library name directly for curl instead of CURL::libcurl`
219	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
220	`${CURL_ROOT_DIR}/lib/libcurl.so`
221	`${ANDROID_PACKAGE_ABI_DIR}/libcurl.so`
222	`)`
223	`endif()`
224	`endif()`
225	`endif()`

microsoft/onnxruntime-extensions

Branches

Tags

Clone