microsoft/onnxruntime-extensions

Public

mirrored from https://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

3d0392ceef534340a8f5fc0f4dddc4935aa314bf

Find a branch or tag

Branches

3d0392ceef534340a8f5fc0f4dddc4935aa314bf

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

182lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT ANDROID)`
5	`find_package(JNI REQUIRED)`
6	`endif()`
7
8	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
9	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
10	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
11
12	`# use the gradle wrapper if it exists`
13	`if(EXISTS "${JAVA_ROOT}/gradlew")`
14	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
15	`else()`
16	`# fall back to gradle on our PATH`
17	`find_program(GRADLE_EXECUTABLE gradle)`
18	`if(NOT GRADLE_EXECUTABLE)`
19	`message(SEND_ERROR "Gradle installation not found")`
20	`endif()`
21	`endif()`
22	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
23
24	`# Specify the Java source files`
25	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
26	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
27	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
28	`# this jar is solely used to signaling mechanism for dependency management in CMake`
29	`# if any of the Java sources change, the jar (and generated headers) will be regenerated and the onnxruntime_extensions4j_jni target will be rebuilt`
30	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
31	`if(WIN32)`
32	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
33	`elseif (ANDROID)`
34	`# For Android build, we may run gradle multiple times in same build,`
35	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
36	`# it is better to not keep a daemon running`
37	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
38	`endif()`
39
40	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
41	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
42	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP} DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src})`
43	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
44	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
45	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
46
47	`# Specify the native sources`
48	`file(GLOB onnxruntime_extensions4j_native_src`
49	`"${JAVA_ROOT}/src/main/native/*.c"`
50	`"${JAVA_ROOT}/src/main/native/*.h"`
51	`"${PROJECT_SOURCE_DIR}/include/*.h"`
52	`)`
53	`# Build the JNI library`
54	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
55
56	`# depend on java sources. if they change, the JNI should recompile`
57	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
58	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
59	`# the JNI headers are generated in the onnxruntime_extensions4j target`
60	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
61
62	`# use shared lib for extensions on Android as NuGet requires the extensions .so`
63	`if (ANDROID AND _BUILD_SHARED_LIBRARY)`
64	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE extensions_shared)`
65	`else()`
66	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
67	`endif()`
68
69	`standardize_output_folder(onnxruntime_extensions4j_jni)`
70
71	`# Set platform and arch for packaging`
72	`# Checks the names set by MLAS on non-Windows platforms first`
73	`if(APPLE)`
74	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
75	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
76	`if(ONNXRUNTIME4J_OSX_ARCH)`
77	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
78	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
79	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
80	`else()`
81	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
82	`endif()`
83	`else()`
84	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
85	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
86	`endif()`
87	`if(JNI_ARCH STREQUAL "x86_64")`
88	`set(JNI_ARCH x64)`
89	`elseif(JNI_ARCH STREQUAL "arm64")`
90	`set(JNI_ARCH aarch64)`
91	`endif()`
92	`elseif (ANDROID)`
93	`set(JNI_ARCH ${ANDROID_ABI})`
94	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
95	`set(JNI_ARCH x64)`
96	`else()`
97	`# Now mirror the checks used with MSVC`
98	`if(MSVC)`
99	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
100	`set(JNI_ARCH aarch64)`
101	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
102	`set(JNI_ARCH x64)`
103	`else()`
104	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
105	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
106	`endif()`
107	`else()`
108	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
109	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
110	`endif()`
111	`endif()`
112
113	`if (WIN32)`
114	`set(JAVA_PLAT "win")`
115	`elseif (APPLE)`
116	`set(JAVA_PLAT "osx")`
117	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
118	`set(JAVA_PLAT "linux")`
119	`else()`
120	`# We don't do distribution for Android`
121	`# Set for completeness`
122	`set(JAVA_PLAT "android")`
123	`endif()`
124
125	`# Similar to Nuget schema`
126	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
127
128	`# expose native libraries to the gradle build process`
129	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
130	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
131	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
132	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
133	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
134	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
135	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
136
137	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
138	`if (WIN32)`
139	`#Our static analysis plugin set /p:LinkCompiled=false`
140	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
141	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
142	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
143	`endif()`
144	`else()`
145	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
146	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
147	`endif()`
148
149	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
150	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
151	`if(WIN32)`
152	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
153	`elseif (ANDROID)`
154	`# For Android build, we may run gradle multiple times in same build,`
155	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
156	`# it is better to not keep a daemon running`
157	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
158	`endif()`
159
160	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
161	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
162
163	`if (ANDROID)`
164	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
165	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
166
167	`# Copy onnxruntime_extensions4j_jni.so and ortextensions.so for building Android AAR package and use in NuGet`
168	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
169	`POST_BUILD`
170	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
171	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
172	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
173	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
174
175	`if (_BUILD_SHARED_LIBRARY)`
176	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
177	`POST_BUILD`
178	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
179	`$<TARGET_FILE:extensions_shared>`
180	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:extensions_shared>)`
181	`endif()`
182	`endif()`
183

microsoft/onnxruntime-extensions

Branches

Tags

Clone