microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

545c18c64abcff9e198828fae267fceaa2ac1a98

Find a branch or tag

Branches

545c18c64abcff9e198828fae267fceaa2ac1a98

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

172lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT CMAKE_SYSTEM_NAME STREQUAL "Android")`
5	`find_package(JNI REQUIRED)`
6	`endif()`
7
8	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
9	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
10	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
11
12	`# use the gradle wrapper if it exists`
13	`if(EXISTS "${JAVA_ROOT}/gradlew")`
14	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
15	`else()`
16	`# fall back to gradle on our PATH`
17	`find_program(GRADLE_EXECUTABLE gradle)`
18	`if(NOT GRADLE_EXECUTABLE)`
19	`message(SEND_ERROR "Gradle installation not found")`
20	`endif()`
21	`endif()`
22	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
23
24	`# Specify the Java source files`
25	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
26	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
27	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
28	`# this jar is solely used to signaling mechanism for dependency management in CMake`
29	`# if any of the Java sources change, the jar (and generated headers) will be regenerated and the onnxruntime_extensions4j_jni target will be rebuilt`
30	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
31	`if(WIN32)`
32	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
33	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
34	`# For Android build, we may run gradle multiple times in same build,`
35	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
36	`# it is better to not keep a daemon running`
37	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
38	`endif()`
39
40	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
41	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
42	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP} DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src})`
43	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
44	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
45	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
46
47	`# Specify the native sources`
48	`file(GLOB onnxruntime_extensions4j_native_src`
49	`"${JAVA_ROOT}/src/main/native/*.c"`
50	`"${JAVA_ROOT}/src/main/native/*.h"`
51	`"${PROJECT_SOURCE_DIR}/include/*.h"`
52	`)`
53	`# Build the JNI library`
54	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
55
56	`# depend on java sources. if they change, the JNI should recompile`
57	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
58	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
59	`# the JNI headers are generated in the onnxruntime_extensions4j target`
60	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
61	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
62	`standardize_output_folder(onnxruntime_extensions4j_jni)`
63
64	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
65	`if (OCOS_ENABLE_SPM_TOKENIZER)`
66	`target_link_libraries(onnxruntime_extensions4j_jni PUBLIC log)`
67	`endif()`
68	`endif()`
69	`# Set platform and arch for packaging`
70	`# Checks the names set by MLAS on non-Windows platforms first`
71	`if(APPLE)`
72	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
73	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
74	`if(ONNXRUNTIME4J_OSX_ARCH)`
75	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
76	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
77	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
78	`else()`
79	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
80	`endif()`
81	`else()`
82	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
83	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
84	`endif()`
85	`if(JNI_ARCH STREQUAL "x86_64")`
86	`set(JNI_ARCH x64)`
87	`elseif(JNI_ARCH STREQUAL "arm64")`
88	`set(JNI_ARCH aarch64)`
89	`endif()`
90	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
91	`set(JNI_ARCH ${ANDROID_ABI})`
92	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
93	`set(JNI_ARCH x64)`
94	`else()`
95	`# Now mirror the checks used with MSVC`
96	`if(MSVC)`
97	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
98	`set(JNI_ARCH aarch64)`
99	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
100	`set(JNI_ARCH x64)`
101	`else()`
102	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
103	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
104	`endif()`
105	`else()`
106	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
107	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
108	`endif()`
109	`endif()`
110
111	`if (WIN32)`
112	`set(JAVA_PLAT "win")`
113	`elseif (APPLE)`
114	`set(JAVA_PLAT "osx")`
115	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
116	`set(JAVA_PLAT "linux")`
117	`else()`
118	`# We don't do distribution for Android`
119	`# Set for completeness`
120	`set(JAVA_PLAT "android")`
121	`endif()`
122
123	`# Similar to Nuget schema`
124	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
125
126	`# expose native libraries to the gradle build process`
127	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
128	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
129	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
130	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
131	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
132	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
133	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
134
135	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
136	`if (WIN32)`
137	`#Our static analysis plugin set /p:LinkCompiled=false`
138	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
139	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
140	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
141	`endif()`
142	`else()`
143	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
144	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE:onnxruntime_extensions4j_jni> ${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
145	`endif()`
146
147	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
148	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
149	`if(WIN32)`
150	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
151	`elseif (CMAKE_SYSTEM_NAME STREQUAL "Android")`
152	`# For Android build, we may run gradle multiple times in same build,`
153	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
154	`# it is better to not keep a daemon running`
155	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
156	`endif()`
157
158	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
159	`add_custom_command(TARGET onnxruntime_extensions4j_jni POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
160
161	`if (CMAKE_SYSTEM_NAME STREQUAL "Android")`
162	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
163	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
164
165	`# Copy onnxruntime_extensions4j_jni.so for building Android AAR package`
166	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
167	`POST_BUILD`
168	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
169	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
170	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
171	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
172	`endif()`
173

microsoft/onnxruntime-extensions

Branches

Tags

Clone