microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

5e991fbb80f4a66a7e6f8914e15008c3c8595d6c

Find a branch or tag

Branches

5e991fbb80f4a66a7e6f8914e15008c3c8595d6c

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

228lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`# Copyright (c) Microsoft Corporation. All rights reserved.`
2	`# Licensed under the MIT License.`
3
4	`include(FindJava)`
5	`find_package(Java REQUIRED)`
6	`include(UseJava)`
7	`if (NOT ANDROID)`
8	`set(JAVA_AWT_LIBRARY NotNeeded)`
9	`set(JAVA_AWT_INCLUDE_PATH NotNeeded)`
10	`find_package(JNI REQUIRED)`
11	`endif()`
12
13	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
14	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
15	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
16
17	`# use the gradle wrapper if it exists`
18	`if(EXISTS "${JAVA_ROOT}/gradlew")`
19	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
20	`else()`
21	`# fall back to gradle on our PATH`
22	`find_program(GRADLE_EXECUTABLE gradle)`
23	`if(NOT GRADLE_EXECUTABLE)`
24	`message(SEND_ERROR "Gradle installation not found")`
25	`endif()`
26	`endif()`
27	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
28
29	`# Specify the Java source files`
30	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
31	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
32	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
33	`# this jar is solely used to signaling mechanism for dependency management in CMake`
34	`# if any of the Java sources change, the jar (and generated headers) will be regenerated`
35	`# and the onnxruntime_extensions4j_jni target will be rebuilt`
36	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
37	`if(WIN32)`
38	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
39	`elseif (ANDROID)`
40	`# For Android build, we may run gradle multiple times in same build,`
41	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
42	`# it is better to not keep a daemon running`
43	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
44	`endif()`
45
46	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
47	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
48	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP}`
49	`DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src} ortcustomops)`
50	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
51	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
52	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
53
54	`# Specify the native sources`
55	`file(GLOB onnxruntime_extensions4j_native_src`
56	`"${JAVA_ROOT}/src/main/native/*.c"`
57	`"${JAVA_ROOT}/src/main/native/*.h"`
58	`"${PROJECT_SOURCE_DIR}/include/*.h"`
59	`)`
60	`if(WIN32)`
61	`list(APPEND onnxruntime_extensions4j_native_src "${JAVA_ROOT}/ortx_jni.def")`
62	`endif()`
63	`# Build the JNI library`
64	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
65
66	`# depend on java sources. if they change, the JNI should recompile`
67	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
68	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
69	`# the JNI headers are generated in the onnxruntime_extensions4j target`
70	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
71
72	`# use shared lib for extensions on Android as NuGet requires the extensions .so`
73	`if (ANDROID AND _BUILD_SHARED_LIBRARY)`
74	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE extensions_shared)`
75	`else()`
76	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
77	`endif()`
78
79	`if(LINUX)`
80	`set_property(TARGET onnxruntime_extensions4j_jni APPEND_STRING PROPERTY LINK_FLAGS`
81	`" -Wl,--version-script -Wl,${JAVA_ROOT}/ortx_jni.ver")`
82	`# strip if not a debug build`
83	`if(NOT CMAKE_BUILD_TYPE STREQUAL "Debug")`
84	`set_property(TARGET onnxruntime_extensions4j_jni APPEND_STRING PROPERTY LINK_FLAGS " -Wl,-s")`
85	`endif()`
86	`endif()`
87
88	`standardize_output_folder(onnxruntime_extensions4j_jni)`
89
90	`# Set platform and arch for packaging`
91	`# Checks the names set by MLAS on non-Windows platforms first`
92	`if(APPLE)`
93	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
94	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
95	`if(ONNXRUNTIME4J_OSX_ARCH)`
96	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
97	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
98	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
99	`else()`
100	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
101	`endif()`
102	`else()`
103	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
104	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
105	`endif()`
106	`if(JNI_ARCH STREQUAL "x86_64")`
107	`set(JNI_ARCH x64)`
108	`elseif(JNI_ARCH STREQUAL "arm64")`
109	`set(JNI_ARCH aarch64)`
110	`endif()`
111	`elseif (ANDROID)`
112	`set(JNI_ARCH ${ANDROID_ABI})`
113	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
114	`set(JNI_ARCH x64)`
115	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "aarch64")`
116	`set(JNI_ARCH aarch64)`
117	`else()`
118	`# Now mirror the checks used with MSVC`
119	`if(MSVC)`
120	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
121	`set(JNI_ARCH aarch64)`
122	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
123	`set(JNI_ARCH x64)`
124	`else()`
125	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
126	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
127	`endif()`
128	`else()`
129	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
130	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
131	`endif()`
132	`endif()`
133
134	`if (WIN32)`
135	`set(JAVA_PLAT "win")`
136	`elseif (APPLE)`
137	`set(JAVA_PLAT "osx")`
138	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
139	`set(JAVA_PLAT "linux")`
140	`else()`
141	`# We don't do distribution for Android`
142	`# Set for completeness`
143	`set(JAVA_PLAT "android")`
144	`endif()`
145
146	`# Similar to Nuget schema`
147	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
148
149	`# expose native libraries to the gradle build process`
150	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
151	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
152	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
153	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
154	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
155	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
156	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
157
158	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
159	`if (WIN32)`
160	`#Our static analysis plugin set /p:LinkCompiled=false`
161	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
162	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
163	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
164	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
165	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
166	`endif()`
167	`else()`
168	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
169	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
170	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
171	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
172	`endif()`
173
174	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
175	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
176	`if(WIN32)`
177	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
178	`elseif (ANDROID)`
179	`# For Android build, we may run gradle multiple times in same build,`
180	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
181	`# it is better to not keep a daemon running`
182	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
183	`endif()`
184
185	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
186	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
187	`POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
188
189	`if (ANDROID)`
190	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
191	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
192
193	`# Copy onnxruntime_extensions4j_jni.so and ortextensions.so for building Android AAR package and use in NuGet`
194	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
195	`POST_BUILD`
196	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
197	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
198	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
199	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
200
201	`if (_BUILD_SHARED_LIBRARY)`
202	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
203	`POST_BUILD`
204	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
205	`$<TARGET_FILE:extensions_shared>`
206	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:extensions_shared>)`
207	`endif()`
208
209	`if (OCOS_ENABLE_AZURE)`
210	`# if we do a shared build of curl/openssl libcurl.so will exist, and we need to copy these files`
211	`# for inclusion in the AAR`
212	`if(EXISTS "${CURL_ROOT_DIR}/lib/libcurl.so")`
213	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
214	`POST_BUILD`
215	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
216	`$<TARGET_FILE:OpenSSL::Crypto>`
217	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::Crypto>`
218	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
219	`$<TARGET_FILE:OpenSSL::SSL>`
220	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::SSL>`
221	`# not sure why but we need to use the library name directly for curl instead of CURL::libcurl`
222	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
223	`${CURL_ROOT_DIR}/lib/libcurl.so`
224	`${ANDROID_PACKAGE_ABI_DIR}/libcurl.so`
225	`)`
226	`endif()`
227	`endif()`
228	`endif()`
229

microsoft/onnxruntime-extensions

Branches

Tags

Clone