microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

9e7f8e5b1dd903dfdbb526fdb68db0ef83d9a7e8

Find a branch or tag

Branches

9e7f8e5b1dd903dfdbb526fdb68db0ef83d9a7e8

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

189lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT ANDROID)`
5	`find_package(JNI REQUIRED)`
6	`endif()`
7
8	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
9	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
10	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
11
12	`# use the gradle wrapper if it exists`
13	`if(EXISTS "${JAVA_ROOT}/gradlew")`
14	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
15	`else()`
16	`# fall back to gradle on our PATH`
17	`find_program(GRADLE_EXECUTABLE gradle)`
18	`if(NOT GRADLE_EXECUTABLE)`
19	`message(SEND_ERROR "Gradle installation not found")`
20	`endif()`
21	`endif()`
22	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
23
24	`# Specify the Java source files`
25	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
26	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
27	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
28	`# this jar is solely used to signaling mechanism for dependency management in CMake`
29	`# if any of the Java sources change, the jar (and generated headers) will be regenerated`
30	`# and the onnxruntime_extensions4j_jni target will be rebuilt`
31	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
32	`if(WIN32)`
33	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
34	`elseif (ANDROID)`
35	`# For Android build, we may run gradle multiple times in same build,`
36	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
37	`# it is better to not keep a daemon running`
38	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
39	`endif()`
40
41	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
42	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
43	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP}`
44	`DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src} ortcustomops)`
45	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
46	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
47	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
48
49	`# Specify the native sources`
50	`file(GLOB onnxruntime_extensions4j_native_src`
51	`"${JAVA_ROOT}/src/main/native/*.c"`
52	`"${JAVA_ROOT}/src/main/native/*.h"`
53	`"${PROJECT_SOURCE_DIR}/include/*.h"`
54	`)`
55	`# Build the JNI library`
56	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
57
58	`# depend on java sources. if they change, the JNI should recompile`
59	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
60	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
61	`# the JNI headers are generated in the onnxruntime_extensions4j target`
62	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
63
64	`# use shared lib for extensions on Android as NuGet requires the extensions .so`
65	`if (ANDROID AND _BUILD_SHARED_LIBRARY)`
66	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE extensions_shared)`
67	`else()`
68	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
69	`endif()`
70
71	`standardize_output_folder(onnxruntime_extensions4j_jni)`
72
73	`# Set platform and arch for packaging`
74	`# Checks the names set by MLAS on non-Windows platforms first`
75	`if(APPLE)`
76	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
77	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
78	`if(ONNXRUNTIME4J_OSX_ARCH)`
79	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
80	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
81	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
82	`else()`
83	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
84	`endif()`
85	`else()`
86	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
87	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
88	`endif()`
89	`if(JNI_ARCH STREQUAL "x86_64")`
90	`set(JNI_ARCH x64)`
91	`elseif(JNI_ARCH STREQUAL "arm64")`
92	`set(JNI_ARCH aarch64)`
93	`endif()`
94	`elseif (ANDROID)`
95	`set(JNI_ARCH ${ANDROID_ABI})`
96	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
97	`set(JNI_ARCH x64)`
98	`else()`
99	`# Now mirror the checks used with MSVC`
100	`if(MSVC)`
101	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
102	`set(JNI_ARCH aarch64)`
103	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
104	`set(JNI_ARCH x64)`
105	`else()`
106	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
107	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
108	`endif()`
109	`else()`
110	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
111	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
112	`endif()`
113	`endif()`
114
115	`if (WIN32)`
116	`set(JAVA_PLAT "win")`
117	`elseif (APPLE)`
118	`set(JAVA_PLAT "osx")`
119	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
120	`set(JAVA_PLAT "linux")`
121	`else()`
122	`# We don't do distribution for Android`
123	`# Set for completeness`
124	`set(JAVA_PLAT "android")`
125	`endif()`
126
127	`# Similar to Nuget schema`
128	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
129
130	`# expose native libraries to the gradle build process`
131	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
132	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
133	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
134	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
135	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
136	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
137	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
138
139	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
140	`if (WIN32)`
141	`#Our static analysis plugin set /p:LinkCompiled=false`
142	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
143	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
144	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
145	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
146	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
147	`endif()`
148	`else()`
149	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
150	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
151	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
152	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
153	`endif()`
154
155	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
156	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
157	`if(WIN32)`
158	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
159	`elseif (ANDROID)`
160	`# For Android build, we may run gradle multiple times in same build,`
161	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
162	`# it is better to not keep a daemon running`
163	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
164	`endif()`
165
166	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
167	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
168	`POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
169
170	`if (ANDROID)`
171	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
172	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
173
174	`# Copy onnxruntime_extensions4j_jni.so and ortextensions.so for building Android AAR package and use in NuGet`
175	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
176	`POST_BUILD`
177	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
178	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
179	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
180	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
181
182	`if (_BUILD_SHARED_LIBRARY)`
183	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
184	`POST_BUILD`
185	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
186	`$<TARGET_FILE:extensions_shared>`
187	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:extensions_shared>)`
188	`endif()`
189	`endif()`
190

microsoft/onnxruntime-extensions

Branches

Tags

Clone