microsoft/onnxruntime-extensions
Publicmirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable
cmake/ext_ortlib.cmake
56lines · modecode
| 1 | if(_ONNXRUNTIME_EMBEDDED) |
| 2 | set(ONNXRUNTIME_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/../include/onnxruntime/core/session) |
| 3 | set(ONNXRUNTIME_LIB_DIR "") |
| 4 | elseif(ONNXRUNTIME_PKG_DIR) |
| 5 | set(ONNXRUNTIME_INCLUDE_DIR ${ONNXRUNTIME_PKG_DIR}/include) |
| 6 | set(ONNXRUNTIME_LIB_DIR ${ONNXRUNTIME_PKG_DIR}/lib) |
| 7 | else() |
| 8 | message(STATUS "CMAKE_SYSTEM_PROCESSOR=${CMAKE_SYSTEM_PROCESSOR}") |
| 9 | message(STATUS "CMAKE_GENERATOR_PLATFORM=${CMAKE_GENERATOR_PLATFORM}") |
| 10 | |
| 11 | # 1.15.1 is the latest ORT release. |
| 12 | set(ONNXRUNTIME_VER "1.15.1") |
| 13 | |
| 14 | if(APPLE) |
| 15 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-osx-universal2-${ONNXRUNTIME_VER}.tgz") |
| 16 | elseif(WIN32) |
| 17 | set(ONNXRUNTIME_BINARY_PLATFORM "x64") |
| 18 | |
| 19 | # override if generator platform is set |
| 20 | if (CMAKE_GENERATOR_PLATFORM) |
| 21 | if (CMAKE_GENERATOR_PLATFORM STREQUAL "Win32") |
| 22 | set(ONNXRUNTIME_BINARY_PLATFORM "x86") |
| 23 | elseif (CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64" OR CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64EC") |
| 24 | set(ONNXRUNTIME_BINARY_PLATFORM "arm64") |
| 25 | elseif (CMAKE_GENERATOR_PLATFORM STREQUAL "ARM") |
| 26 | set(ONNXRUNTIME_BINARY_PLATFORM "arm") |
| 27 | endif() |
| 28 | elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "ARM64") |
| 29 | # or if building on arm64 machine |
| 30 | set(ONNXRUNTIME_BINARY_PLATFORM "arm64") |
| 31 | endif() |
| 32 | |
| 33 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-win-${ONNXRUNTIME_BINARY_PLATFORM}-${ONNXRUNTIME_VER}.zip") |
| 34 | else() |
| 35 | # Linux or other, using Linux package to retrieve the headers |
| 36 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-linux-x64-${ONNXRUNTIME_VER}.tgz") |
| 37 | |
| 38 | if(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64") |
| 39 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-linux-aarch64-${ONNXRUNTIME_VER}.tgz") |
| 40 | endif() |
| 41 | endif() |
| 42 | |
| 43 | message(STATUS "ONNX Runtime URL suffix: ${ONNXRUNTIME_URL}") |
| 44 | FetchContent_Declare( |
| 45 | onnxruntime |
| 46 | URL https://github.com/microsoft/onnxruntime/releases/download/${ONNXRUNTIME_URL} |
| 47 | ) |
| 48 | |
| 49 | FetchContent_makeAvailable(onnxruntime) |
| 50 | set(ONNXRUNTIME_INCLUDE_DIR ${onnxruntime_SOURCE_DIR}/include) |
| 51 | set(ONNXRUNTIME_LIB_DIR ${onnxruntime_SOURCE_DIR}/lib) |
| 52 | endif() |
| 53 | |
| 54 | if(NOT EXISTS ${ONNXRUNTIME_INCLUDE_DIR}) |
| 55 | message(FATAL_ERROR "ONNX Runtime headers not found at ${ONNXRUNTIME_INCLUDE_DIR}") |
| 56 | endif() |
| 57 | |