microsoft/onnxruntime-extensions
Publicmirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable
cmake/externals/farmhash/configure.ac
98lines · modecode
| 1 | m4_define([farmhash_major], [1]) |
| 2 | m4_define([farmhash_minor], [1]) |
| 3 | m4_define([farmhash_patchlevel], [0]) |
| 4 | |
| 5 | # Libtool shared library interface versions (current:revision:age) |
| 6 | # Update this value for every release! (A:B:C will map to foo.so.(A-C).C.B) |
| 7 | # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html |
| 8 | m4_define([farmhash_ltversion], [2:0:0]) |
| 9 | |
| 10 | AC_PREREQ([2.65]) |
| 11 | AC_INIT([FarmHash], [farmhash_major.farmhash_minor.farmhash_patchlevel], [farmhash-discuss@googlegroups.com]) |
| 12 | AC_CONFIG_HEADERS([config.h]) |
| 13 | AM_INIT_AUTOMAKE([1.10 no-define foreign]) |
| 14 | LT_PREREQ([2.2]) |
| 15 | LT_INIT |
| 16 | |
| 17 | AC_CONFIG_FILES([Makefile |
| 18 | src/Makefile]) |
| 19 | AC_CONFIG_SRCDIR([src/farmhash.h]) |
| 20 | AC_CONFIG_MACRO_DIR([m4]) |
| 21 | |
| 22 | AC_ARG_ENABLE([optional-builtin-expect], |
| 23 | AS_HELP_STRING("Assume __builtin_expect() may or may not be available. The default is to assume it is available."), |
| 24 | [ farmhash_optional_builtin_expect=true ], |
| 25 | []) |
| 26 | AM_CONDITIONAL([OPTIONAL_BUILTIN_EXPECT], [test x$farmhash_optional_builtin_expect = xtrue ]) |
| 27 | |
| 28 | AC_ARG_ENABLE([optional-builtin-bswap], |
| 29 | AS_HELP_STRING("Assume __builtin_bswap32() and similar may or may not be available. The default is to assume they are available."), |
| 30 | [ farmhash_optional_builtin_bswap=true ], |
| 31 | []) |
| 32 | AM_CONDITIONAL([OPTIONAL_BUILTIN_BSWAP], [test x$farmhash_optional_builtin_bswap = xtrue ]) |
| 33 | |
| 34 | # Checks for programs. |
| 35 | AC_PROG_CXX |
| 36 | AC_LANG([C++]) |
| 37 | AC_C_BIGENDIAN |
| 38 | |
| 39 | # Checks for libraries. |
| 40 | |
| 41 | # Checks for header files. |
| 42 | AC_CHECK_HEADERS([stdint.h stdlib.h]) |
| 43 | |
| 44 | # Checks for typedefs, structures, and compiler characteristics. |
| 45 | #AC_C_INLINE |
| 46 | #AC_TYPE_SIZE_T |
| 47 | #AC_TYPE_SSIZE_T |
| 48 | #AC_TYPE_UINT32_T |
| 49 | #AC_TYPE_UINT64_T |
| 50 | #AC_TYPE_UINT8_T |
| 51 | |
| 52 | # Check for __builtin_expect |
| 53 | AC_MSG_CHECKING([if the compiler supports __builtin_expect]) |
| 54 | AC_COMPILE_IFELSE( |
| 55 | [AC_LANG_PROGRAM(, [[return __builtin_expect(1, 1) ? 1 : 0;]])], |
| 56 | [ |
| 57 | farmhash_have_builtin_expect=yes |
| 58 | AC_MSG_RESULT([yes]) |
| 59 | ], [ |
| 60 | farmhash_have_builtin_expect=no |
| 61 | AC_MSG_RESULT([no]) |
| 62 | ]) |
| 63 | if test x$farmhash_have_builtin_expect = xyes ; then |
| 64 | AC_DEFINE([HAVE_BUILTIN_EXPECT], [1], [Define to 1 if the compiler supports __builtin_expect.]) |
| 65 | fi |
| 66 | |
| 67 | # Check for __builtin_bswap32 |
| 68 | AC_MSG_CHECKING([if the compiler supports __builtin_bswap32]) |
| 69 | AC_COMPILE_IFELSE( |
| 70 | [AC_LANG_PROGRAM(, [[return __builtin_bswap32(0xabcd1234) == 0x3412cdab ? 0 : 1;]])], |
| 71 | [ |
| 72 | farmhash_have_builtin_bswap=yes |
| 73 | AC_MSG_RESULT([yes]) |
| 74 | ], [ |
| 75 | farmhash_have_builtin_bswap=no |
| 76 | AC_MSG_RESULT([no]) |
| 77 | ]) |
| 78 | if test x$farmhash_have_builtin_bswap = xyes ; then |
| 79 | AC_DEFINE([HAVE_BUILTIN_BSWAP], [1], [Define to 1 if the compiler supports __builtin_bswap32.]) |
| 80 | fi |
| 81 | |
| 82 | AC_OUTPUT |
| 83 | |
| 84 | echo \ |
| 85 | "------------------------------------------------- |
| 86 | |
| 87 | ${PACKAGE_NAME} Version ${PACKAGE_VERSION} |
| 88 | |
| 89 | Prefix: '${prefix}'. |
| 90 | Compiler: '${CXX} ${CXXFLAGS}' |
| 91 | |
| 92 | Now type 'make @<:@<target>@:>@' |
| 93 | where the optional <target> is: |
| 94 | all - build everything |
| 95 | check - build and run tests |
| 96 | install - install everything |
| 97 | |
| 98 | --------------------------------------------------" |
| 99 | |