microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

c3c5f1cbb135fc9ccc673ae99b31e4ce6a9e2669

Find a branch or tag

Branches

c3c5f1cbb135fc9ccc673ae99b31e4ce6a9e2669

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

213lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT ANDROID)`
5	`set(JAVA_AWT_LIBRARY NotNeeded)`
6	`set(JAVA_AWT_INCLUDE_PATH NotNeeded)`
7	`find_package(JNI REQUIRED)`
8	`endif()`
9
10	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
11	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
12	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
13
14	`# use the gradle wrapper if it exists`
15	`if(EXISTS "${JAVA_ROOT}/gradlew")`
16	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
17	`else()`
18	`# fall back to gradle on our PATH`
19	`find_program(GRADLE_EXECUTABLE gradle)`
20	`if(NOT GRADLE_EXECUTABLE)`
21	`message(SEND_ERROR "Gradle installation not found")`
22	`endif()`
23	`endif()`
24	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
25
26	`# Specify the Java source files`
27	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
28	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
29	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
30	`# this jar is solely used to signaling mechanism for dependency management in CMake`
31	`# if any of the Java sources change, the jar (and generated headers) will be regenerated`
32	`# and the onnxruntime_extensions4j_jni target will be rebuilt`
33	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
34	`if(WIN32)`
35	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
36	`elseif (ANDROID)`
37	`# For Android build, we may run gradle multiple times in same build,`
38	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
39	`# it is better to not keep a daemon running`
40	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
41	`endif()`
42
43	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
44	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
45	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP}`
46	`DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src} ortcustomops)`
47	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
48	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
49	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
50
51	`# Specify the native sources`
52	`file(GLOB onnxruntime_extensions4j_native_src`
53	`"${JAVA_ROOT}/src/main/native/*.c"`
54	`"${JAVA_ROOT}/src/main/native/*.h"`
55	`"${PROJECT_SOURCE_DIR}/include/*.h"`
56	`)`
57	`# Build the JNI library`
58	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
59
60	`# depend on java sources. if they change, the JNI should recompile`
61	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
62	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
63	`# the JNI headers are generated in the onnxruntime_extensions4j target`
64	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
65
66	`# use shared lib for extensions on Android as NuGet requires the extensions .so`
67	`if (ANDROID AND _BUILD_SHARED_LIBRARY)`
68	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE extensions_shared)`
69	`else()`
70	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
71	`endif()`
72
73	`standardize_output_folder(onnxruntime_extensions4j_jni)`
74
75	`# Set platform and arch for packaging`
76	`# Checks the names set by MLAS on non-Windows platforms first`
77	`if(APPLE)`
78	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
79	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
80	`if(ONNXRUNTIME4J_OSX_ARCH)`
81	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
82	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
83	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
84	`else()`
85	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
86	`endif()`
87	`else()`
88	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
89	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
90	`endif()`
91	`if(JNI_ARCH STREQUAL "x86_64")`
92	`set(JNI_ARCH x64)`
93	`elseif(JNI_ARCH STREQUAL "arm64")`
94	`set(JNI_ARCH aarch64)`
95	`endif()`
96	`elseif (ANDROID)`
97	`set(JNI_ARCH ${ANDROID_ABI})`
98	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
99	`set(JNI_ARCH x64)`
100	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "aarch64")`
101	`set(JNI_ARCH aarch64)`
102	`else()`
103	`# Now mirror the checks used with MSVC`
104	`if(MSVC)`
105	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
106	`set(JNI_ARCH aarch64)`
107	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
108	`set(JNI_ARCH x64)`
109	`else()`
110	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
111	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
112	`endif()`
113	`else()`
114	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
115	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
116	`endif()`
117	`endif()`
118
119	`if (WIN32)`
120	`set(JAVA_PLAT "win")`
121	`elseif (APPLE)`
122	`set(JAVA_PLAT "osx")`
123	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
124	`set(JAVA_PLAT "linux")`
125	`else()`
126	`# We don't do distribution for Android`
127	`# Set for completeness`
128	`set(JAVA_PLAT "android")`
129	`endif()`
130
131	`# Similar to Nuget schema`
132	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
133
134	`# expose native libraries to the gradle build process`
135	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
136	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
137	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
138	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
139	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
140	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
141	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
142
143	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
144	`if (WIN32)`
145	`#Our static analysis plugin set /p:LinkCompiled=false`
146	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
147	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
148	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
149	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
150	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
151	`endif()`
152	`else()`
153	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
154	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
155	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
156	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
157	`endif()`
158
159	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
160	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
161	`if(WIN32)`
162	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
163	`elseif (ANDROID)`
164	`# For Android build, we may run gradle multiple times in same build,`
165	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
166	`# it is better to not keep a daemon running`
167	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
168	`endif()`
169
170	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
171	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
172	`POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
173
174	`if (ANDROID)`
175	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
176	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
177
178	`# Copy onnxruntime_extensions4j_jni.so and ortextensions.so for building Android AAR package and use in NuGet`
179	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
180	`POST_BUILD`
181	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
182	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
183	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
184	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
185
186	`if (_BUILD_SHARED_LIBRARY)`
187	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
188	`POST_BUILD`
189	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
190	`$<TARGET_FILE:extensions_shared>`
191	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:extensions_shared>)`
192	`endif()`
193
194	`if (OCOS_ENABLE_AZURE)`
195	`# if we do a shared build of curl/openssl libcurl.so will exist, and we need to copy these files`
196	`# for inclusion in the AAR`
197	`if(EXISTS "${CURL_ROOT_DIR}/lib/libcurl.so")`
198	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
199	`POST_BUILD`
200	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
201	`$<TARGET_FILE:OpenSSL::Crypto>`
202	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::Crypto>`
203	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
204	`$<TARGET_FILE:OpenSSL::SSL>`
205	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::SSL>`
206	`# not sure why but we need to use the library name directly for curl instead of CURL::libcurl`
207	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
208	`${CURL_ROOT_DIR}/lib/libcurl.so`
209	`${ANDROID_PACKAGE_ABI_DIR}/libcurl.so`
210	`)`
211	`endif()`
212	`endif()`
213	`endif()`
214

microsoft/onnxruntime-extensions

Branches

Tags

Clone