microsoft/onnxruntime-extensions

Public

mirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable

Watch0 Fork0 Star0

Code Commits Issues Pull requests Actions Insights Security

d853d31fc12dbce2bee45430a7b1651d2da5a1f6

Find a branch or tag

Branches

d853d31fc12dbce2bee45430a7b1651d2da5a1f6

Clone

HTTPS

Download ZIP

onnxruntime-extensions/cmake

cmake/ext_java.cmake

209lines · modecode

Raw Download

Latest commit unavailable.

unknown

1	`include(FindJava)`
2	`find_package(Java REQUIRED)`
3	`include(UseJava)`
4	`if (NOT ANDROID)`
5	`set(JAVA_AWT_LIBRARY NotNeeded)`
6	`set(JAVA_JVM_LIBRARY NotNeeded)`
7	`set(JAVA_INCLUDE_PATH2 NotNeeded)`
8	`set(JAVA_AWT_INCLUDE_PATH NotNeeded)`
9	`find_package(JNI REQUIRED)`
10	`endif()`
11
12	`set(JAVA_ROOT ${PROJECT_SOURCE_DIR}/java)`
13	`set(JAVA_OUTPUT_TEMP ${CMAKE_CURRENT_BINARY_DIR}/java-temp)`
14	`set(JAVA_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/java)`
15
16	`# use the gradle wrapper if it exists`
17	`if(EXISTS "${JAVA_ROOT}/gradlew")`
18	`set(GRADLE_EXECUTABLE "${JAVA_ROOT}/gradlew")`
19	`else()`
20	`# fall back to gradle on our PATH`
21	`find_program(GRADLE_EXECUTABLE gradle)`
22	`if(NOT GRADLE_EXECUTABLE)`
23	`message(SEND_ERROR "Gradle installation not found")`
24	`endif()`
25	`endif()`
26	`message(STATUS "Using gradle: ${GRADLE_EXECUTABLE}")`
27
28	`# Specify the Java source files`
29	`file(GLOB_RECURSE onnxruntime_extensions4j_gradle_files "${JAVA_ROOT}/*.gradle")`
30	`file(GLOB_RECURSE onnxruntime_extensions4j_src "${JAVA_ROOT}/src/main/java/ai/onnxruntime/extensions/*.java")`
31	`set(JAVA_OUTPUT_JAR ${JAVA_OUTPUT_TEMP}/build/libs/onnxruntime_extensions.jar)`
32	`# this jar is solely used to signaling mechanism for dependency management in CMake`
33	`# if any of the Java sources change, the jar (and generated headers) will be regenerated`
34	`# and the onnxruntime_extensions4j_jni target will be rebuilt`
35	`set(GRADLE_ARGS --console=plain clean jar -p ${JAVA_ROOT} -x test )`
36	`if(WIN32)`
37	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
38	`elseif (ANDROID)`
39	`# For Android build, we may run gradle multiple times in same build,`
40	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
41	`# it is better to not keep a daemon running`
42	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
43	`endif()`
44
45	`file(MAKE_DIRECTORY ${JAVA_OUTPUT_TEMP})`
46	`add_custom_command(OUTPUT ${JAVA_OUTPUT_JAR}`
47	`COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP}`
48	`DEPENDS ${onnxruntime_extensions4j_gradle_files} ${onnxruntime_extensions4j_src} ortcustomops)`
49	`add_custom_target(onnxruntime_extensions4j DEPENDS ${JAVA_OUTPUT_JAR})`
50	`set_source_files_properties(${JAVA_OUTPUT_JAR} PROPERTIES GENERATED TRUE)`
51	`set_property(TARGET onnxruntime_extensions4j APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${JAVA_OUTPUT_DIR}")`
52
53	`# Specify the native sources`
54	`file(GLOB onnxruntime_extensions4j_native_src`
55	`"${JAVA_ROOT}/src/main/native/*.c"`
56	`"${JAVA_ROOT}/src/main/native/*.h"`
57	`"${PROJECT_SOURCE_DIR}/include/*.h"`
58	`)`
59	`# Build the JNI library`
60	`add_library(onnxruntime_extensions4j_jni SHARED ${onnxruntime_extensions4j_native_src})`
61
62	`# depend on java sources. if they change, the JNI should recompile`
63	`add_dependencies(onnxruntime_extensions4j_jni onnxruntime_extensions4j)`
64	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
65	`# the JNI headers are generated in the onnxruntime_extensions4j target`
66	`target_include_directories(onnxruntime_extensions4j_jni PRIVATE ${JAVA_ROOT}/build/headers ${JNI_INCLUDE_DIRS})`
67
68	`# use shared lib for extensions on Android as NuGet requires the extensions .so`
69	`if (ANDROID AND _BUILD_SHARED_LIBRARY)`
70	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE extensions_shared)`
71	`else()`
72	`target_link_libraries(onnxruntime_extensions4j_jni PRIVATE ortcustomops)`
73	`endif()`
74
75	`standardize_output_folder(onnxruntime_extensions4j_jni)`
76
77	`# Set platform and arch for packaging`
78	`# Checks the names set by MLAS on non-Windows platforms first`
79	`if(APPLE)`
80	`get_target_property(ONNXRUNTIME4J_OSX_ARCH onnxruntime_extensions4j_jni OSX_ARCHITECTURES)`
81	`list(LENGTH ONNXRUNTIME4J_OSX_ARCH ONNXRUNTIME4J_OSX_ARCH_LEN)`
82	`if(ONNXRUNTIME4J_OSX_ARCH)`
83	`if(ONNXRUNTIME4J_OSX_ARCH_LEN LESS_EQUAL 1)`
84	`list(GET ONNXRUNTIME4J_OSX_ARCH 0 JNI_ARCH)`
85	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
86	`else()`
87	`message(FATAL_ERROR "Java is currently not supported for macOS universal")`
88	`endif()`
89	`else()`
90	`set(JNI_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})`
91	`message("Set Java ARCH TO macOS/iOS ${JNI_ARCH}")`
92	`endif()`
93	`if(JNI_ARCH STREQUAL "x86_64")`
94	`set(JNI_ARCH x64)`
95	`elseif(JNI_ARCH STREQUAL "arm64")`
96	`set(JNI_ARCH aarch64)`
97	`endif()`
98	`elseif (ANDROID)`
99	`set(JNI_ARCH ${ANDROID_ABI})`
100	`elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64")`
101	`set(JNI_ARCH x64)`
102	`else()`
103	`# Now mirror the checks used with MSVC`
104	`if(MSVC)`
105	`if(CMAKE_GENERATOR_PLATFORM STREQUAL "ARM64")`
106	`set(JNI_ARCH aarch64)`
107	`elseif(CMAKE_GENERATOR_PLATFORM STREQUAL "x64")`
108	`set(JNI_ARCH x64)`
109	`else()`
110	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
111	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
112	`endif()`
113	`else()`
114	`# if everything else failed then we're on a 32-bit arch and Java isn't supported`
115	`message(FATAL_ERROR "Java is currently not supported on 32-bit x86 architecture")`
116	`endif()`
117	`endif()`
118
119	`if (WIN32)`
120	`set(JAVA_PLAT "win")`
121	`elseif (APPLE)`
122	`set(JAVA_PLAT "osx")`
123	`elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")`
124	`set(JAVA_PLAT "linux")`
125	`else()`
126	`# We don't do distribution for Android`
127	`# Set for completeness`
128	`set(JAVA_PLAT "android")`
129	`endif()`
130
131	`# Similar to Nuget schema`
132	`set(JAVA_OS_ARCH ${JAVA_PLAT}-${JNI_ARCH})`
133
134	`# expose native libraries to the gradle build process`
135	`set(JAVA_PACKAGE_DIR ai/onnxruntime/extensions/native/${JAVA_OS_ARCH})`
136	`set(JAVA_NATIVE_LIB_DIR ${JAVA_OUTPUT_DIR}/native-lib)`
137	`set(JAVA_NATIVE_JNI_DIR ${JAVA_OUTPUT_DIR}/native-jni)`
138	`set(JAVA_PACKAGE_LIB_DIR ${JAVA_NATIVE_LIB_DIR}/${JAVA_PACKAGE_DIR})`
139	`set(JAVA_PACKAGE_JNI_DIR ${JAVA_NATIVE_JNI_DIR}/${JAVA_PACKAGE_DIR})`
140	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_LIB_DIR})`
141	`file(MAKE_DIRECTORY ${JAVA_PACKAGE_JNI_DIR})`
142
143	`# On Windows TARGET_LINKER_FILE_NAME is the .lib, TARGET_FILE_NAME is the .dll`
144	`if (WIN32)`
145	`#Our static analysis plugin set /p:LinkCompiled=false`
146	`if(NOT onnxruntime_extensions_ENABLE_STATIC_ANALYSIS)`
147	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
148	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
149	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
150	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_FILE_NAME:onnxruntime_extensions4j_jni>)`
151	`endif()`
152	`else()`
153	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
154	`POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different`
155	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
156	`${JAVA_PACKAGE_JNI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
157	`endif()`
158
159	`# run the build process (this copies the results back into CMAKE_CURRENT_BINARY_DIR)`
160	`set(GRADLE_ARGS --console=plain cmakeBuild -p ${JAVA_ROOT} -DcmakeBuildDir=${CMAKE_CURRENT_BINARY_DIR})`
161	`if(WIN32)`
162	`set(GRADLE_ARGS ${GRADLE_ARGS} -Dorg.gradle.daemon=false)`
163	`elseif (ANDROID)`
164	`# For Android build, we may run gradle multiple times in same build,`
165	`# sometimes gradle JVM will run out of memory if we keep the daemon running`
166	`# it is better to not keep a daemon running`
167	`set(GRADLE_ARGS ${GRADLE_ARGS} --no-daemon)`
168	`endif()`
169
170	`message(STATUS "GRADLE_ARGS: ${GRADLE_ARGS}")`
171	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
172	`POST_BUILD COMMAND ${GRADLE_EXECUTABLE} ${GRADLE_ARGS} WORKING_DIRECTORY ${JAVA_OUTPUT_TEMP})`
173
174	`if (ANDROID)`
175	`set(ANDROID_PACKAGE_JNILIBS_DIR ${JAVA_OUTPUT_DIR}/android)`
176	`set(ANDROID_PACKAGE_ABI_DIR ${ANDROID_PACKAGE_JNILIBS_DIR}/${ANDROID_ABI})`
177
178	`# Copy onnxruntime_extensions4j_jni.so and ortextensions.so for building Android AAR package and use in NuGet`
179	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
180	`POST_BUILD`
181	`COMMAND ${CMAKE_COMMAND} -E make_directory ${ANDROID_PACKAGE_ABI_DIR}`
182	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
183	`$<TARGET_FILE:onnxruntime_extensions4j_jni>`
184	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:onnxruntime_extensions4j_jni>)`
185
186	`if (_BUILD_SHARED_LIBRARY)`
187	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
188	`POST_BUILD`
189	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
190	`$<TARGET_FILE:extensions_shared>`
191	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:extensions_shared>)`
192	`endif()`
193
194	`if (OCOS_ENABLE_AZURE)`
195	`add_custom_command(TARGET onnxruntime_extensions4j_jni`
196	`POST_BUILD`
197	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
198	`$<TARGET_FILE:OpenSSL::Crypto>`
199	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::Crypto>`
200	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
201	`$<TARGET_FILE:OpenSSL::SSL>`
202	`${ANDROID_PACKAGE_ABI_DIR}/$<TARGET_LINKER_FILE_NAME:OpenSSL::SSL>`
203	`# not sure why but we need to use the library name directly for curl instead of CURL::libcurl`
204	`COMMAND ${CMAKE_COMMAND} -E copy_if_different`
205	`${CURL_ROOT_DIR}/lib/libcurl.so`
206	`${ANDROID_PACKAGE_ABI_DIR}/libcurl.so`
207	`)`
208	`endif()`
209	`endif()`
210

microsoft/onnxruntime-extensions

Branches

Tags

Clone