microsoft/onnxruntime-extensions
Publicmirrored fromhttps://github.com/microsoft/onnxruntime-extensionsAvailable
cmake/ext_ortlib.cmake
46lines · modecode
| 1 | if(_ONNXRUNTIME_EMBEDDED) |
| 2 | set(ONNXRUNTIME_INCLUDE_DIR ${CMAKE_SOURCE_DIR}/../include/onnxruntime/core/session) |
| 3 | set(ONNXRUNTIME_LIB_DIR "") |
| 4 | elseif(ONNXRUNTIME_PKG_DIR) |
| 5 | set(ONNXRUNTIME_INCLUDE_DIR ${ONNXRUNTIME_PKG_DIR}/include) |
| 6 | set(ONNXRUNTIME_LIB_DIR ${ONNXRUNTIME_PKG_DIR}/lib) |
| 7 | else() |
| 8 | # default to 1.10.0 if not specified |
| 9 | set(ONNXRUNTIME_VER "1.10.0" CACHE STRING "ONNX Runtime version") |
| 10 | |
| 11 | if(CMAKE_HOST_APPLE) |
| 12 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-osx-universal2-${ONNXRUNTIME_VER}.tgz") |
| 13 | elseif(CMAKE_HOST_WIN32) |
| 14 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-win-x64-${ONNXRUNTIME_VER}.zip") |
| 15 | |
| 16 | if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm64") |
| 17 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-win-arm64-${ONNXRUNTIME_VER}.zip") |
| 18 | endif() |
| 19 | else() |
| 20 | # Linux or other, using Linux package to retrieve the headers |
| 21 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-linux-x64-${ONNXRUNTIME_VER}.tgz") |
| 22 | |
| 23 | if(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64") |
| 24 | set(ONNXRUNTIME_URL "v${ONNXRUNTIME_VER}/onnxruntime-linux-aarch64-${ONNXRUNTIME_VER}.tgz") |
| 25 | endif() |
| 26 | endif() |
| 27 | |
| 28 | # Avoid warning about DOWNLOAD_EXTRACT_TIMESTAMP in CMake 3.24: |
| 29 | if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.24.0") |
| 30 | cmake_policy(SET CMP0135 NEW) |
| 31 | endif() |
| 32 | |
| 33 | message(STATUS "ONNX Runtime URL suffix: ${ONNXRUNTIME_URL}") |
| 34 | FetchContent_Declare( |
| 35 | onnxruntime |
| 36 | URL https://github.com/microsoft/onnxruntime/releases/download/${ONNXRUNTIME_URL} |
| 37 | ) |
| 38 | |
| 39 | FetchContent_makeAvailable(onnxruntime) |
| 40 | set(ONNXRUNTIME_INCLUDE_DIR ${onnxruntime_SOURCE_DIR}/include) |
| 41 | set(ONNXRUNTIME_LIB_DIR ${onnxruntime_SOURCE_DIR}/lib) |
| 42 | endif() |
| 43 | |
| 44 | if(NOT EXISTS ${ONNXRUNTIME_INCLUDE_DIR}) |
| 45 | message(FATAL_ERROR "ONNX Runtime headers not found at ${ONNXRUNTIME_INCLUDE_DIR}") |
| 46 | endif() |