openai/openai-java
Publicmirrored from https://github.com/openai/openai-javaAvailable
openai-java-core/build.gradle.kts
62lines · modecode
| 1 | plugins { |
| 2 | id("java") |
| 3 | id("openai.kotlin") |
| 4 | id("openai.publish") |
| 5 | } |
| 6 | |
| 7 | configurations.all { |
| 8 | resolutionStrategy { |
| 9 | // Compile and test against a lower Jackson version to ensure we're compatible with it. Note that |
| 10 | // we generally support 2.13.4, but test against 2.14.0 because 2.13.4 has some annoying (but |
| 11 | // niche) bugs (users should upgrade if they encounter them). We publish with a higher version |
| 12 | // (see below) to ensure users depend on a secure version by default. |
| 13 | force("com.fasterxml.jackson.core:jackson-core:2.14.0") |
| 14 | force("com.fasterxml.jackson.core:jackson-databind:2.14.0") |
| 15 | force("com.fasterxml.jackson.core:jackson-annotations:2.14.0") |
| 16 | force("com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.14.0") |
| 17 | force("com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.14.0") |
| 18 | force("com.fasterxml.jackson.module:jackson-module-kotlin:2.14.0") |
| 19 | } |
| 20 | } |
| 21 | |
| 22 | dependencies { |
| 23 | api("com.fasterxml.jackson.core:jackson-core:2.18.2") |
| 24 | api("com.fasterxml.jackson.core:jackson-databind:2.18.2") |
| 25 | api("com.google.errorprone:error_prone_annotations:2.33.0") |
| 26 | api("io.swagger.core.v3:swagger-annotations:2.2.31") |
| 27 | |
| 28 | implementation("com.fasterxml.jackson.core:jackson-annotations:2.18.2") |
| 29 | implementation("com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.18.2") |
| 30 | implementation("com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.18.2") |
| 31 | implementation("com.fasterxml.jackson.module:jackson-module-kotlin:2.18.2") |
| 32 | implementation("com.github.victools:jsonschema-generator:4.38.0") |
| 33 | implementation("com.github.victools:jsonschema-module-jackson:4.38.0") |
| 34 | implementation("com.github.victools:jsonschema-module-swagger-2:4.38.0") |
| 35 | |
| 36 | testImplementation(kotlin("test")) |
| 37 | testImplementation(project(":openai-java-client-okhttp")) |
| 38 | testImplementation("com.github.tomakehurst:wiremock-jre8:2.35.2") |
| 39 | testImplementation("org.assertj:assertj-core:3.27.7") |
| 40 | testImplementation("org.junit.jupiter:junit-jupiter-api:5.9.3") |
| 41 | testImplementation("org.junit.jupiter:junit-jupiter-params:5.9.3") |
| 42 | testImplementation("org.junit-pioneer:junit-pioneer:1.9.1") |
| 43 | testImplementation("org.mockito:mockito-core:5.14.2") |
| 44 | testImplementation("org.mockito:mockito-junit-jupiter:5.14.2") |
| 45 | testImplementation("org.mockito.kotlin:mockito-kotlin:4.1.0") |
| 46 | } |
| 47 | |
| 48 | if (project.hasProperty("graalvmAgent")) { |
| 49 | java { |
| 50 | toolchain { |
| 51 | languageVersion.set(JavaLanguageVersion.of(21)) |
| 52 | vendor.set(JvmVendorSpec.GRAAL_VM) |
| 53 | } |
| 54 | } |
| 55 | |
| 56 | tasks.test { |
| 57 | maxParallelForks = 1 |
| 58 | forkEvery = 0 |
| 59 | jvmArgs = |
| 60 | listOf("-agentlib:native-image-agent=config-output-dir=src/main/resources/META-INF/native-image") |
| 61 | } |
| 62 | } |